# Maintainer: Joel Holdsworth <jholdsworth@nvidia.com>

_realname=semver
pkgbase=mingw-w64-python-${_realname}
pkgname=("${MINGW_PACKAGE_PREFIX}-python-${_realname}")
pkgver=3.0.4
pkgrel=1
pkgdesc="Python package to work with Semantic Versioning (mingw-w64)"
arch=('any')
mingw_arch=('ucrt64' 'clang64' 'clangarm64')
msys2_references=(
  'archlinux: python-semver'
  'purl: pkg:pypi/semver'
)
license=('spdx:BSD-3-Clause')
url='https://github.com/python-semver/python-semver'
msys2_repository_url='https://github.com/python-semver/python-semver'
msys2_issue_tracker_url='https://github.com/python-semver/python-semver/issues'
msys2_documentation_url='https://python-semver.readthedocs.io/en/latest/'
depends=("${MINGW_PACKAGE_PREFIX}-python")
makedepends=("${MINGW_PACKAGE_PREFIX}-python-build"
             "${MINGW_PACKAGE_PREFIX}-python-installer"
             "${MINGW_PACKAGE_PREFIX}-python-setuptools")
checkdepends=("${MINGW_PACKAGE_PREFIX}-python-pytest"
              "${MINGW_PACKAGE_PREFIX}-python-pytest-cov")
options=('!strip')
source=("https://pypi.org/packages/source/${_realname::1}/${_realname}/${_realname}-${pkgver}.tar.gz")
sha256sums=('afc7d8c584a5ed0a11033af086e8af226a9c0b206f313e0301f8dd7b6b589602')

build() {
  cp -r "${_realname}-${pkgver}" "build-${MSYSTEM}" && cd "build-${MSYSTEM}"
  python -m build --wheel --skip-dependency-check --no-isolation
}

check() {
  cd "build-${MSYSTEM}"
  python -m pytest || warning "Tests failed"
}

package() {
  cd "build-${MSYSTEM}"

  MSYS2_ARG_CONV_EXCL="--prefix=" \
    python -m installer --prefix=${MINGW_PREFIX} \
    --destdir="${pkgdir}" dist/*.whl

  install -Dm644 LICENSE.txt "${pkgdir}${MINGW_PREFIX}/share/licenses/python-${_realname}/LICENSE.txt"
}
